build: scaffold Spigot plugin project

2026-08-08 13:10:04 -04:00
parent a01f36db86
commit 152cac0740
15 changed files with 664 additions and 9 deletions
@@ -0,0 +1,45 @@
+plugins {
+    java
+}
+
+group = "games.dmg"
+version = providers.gradleProperty("releaseVersion")
+    .orElse("0.1.0-SNAPSHOT")
+    .get()
+
+repositories {
+    mavenCentral()
+    maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
+}
+
+java {
+    toolchain {
+        languageVersion = JavaLanguageVersion.of(17)
+    }
+}
+
+tasks.withType<JavaCompile>().configureEach {
+    options.compilerArgs.addAll(listOf("-Xlint:all", "-Werror"))
+}
+
+dependencies {
+    compileOnly("org.spigotmc:spigot-api:26.2-R0.1-SNAPSHOT")
+
+    testImplementation("org.spigotmc:spigot-api:26.2-R0.1-SNAPSHOT")
+    testImplementation(platform("org.junit:junit-bom:5.13.4"))
+    testImplementation("org.junit.jupiter:junit-jupiter")
+    testImplementation("org.yaml:snakeyaml:2.4")
+    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
+}
+
+tasks.test {
+    useJUnitPlatform()
+}
+
+val pluginVersion = version
+
+tasks.processResources {
+    filesMatching("plugin.yml") {
+        expand("version" to pluginVersion)
+    }
+}